【脚本】txt装备展示案例-容器
我这里是做的是分开展示，一次只展示一个大陆，不是一次把所有大陆展示出来，这样容易卡顿，如果你有更好的方式可以分享讨论[@游戏攻略界面]{
#IF
#ACT
MOV N$大陆标识 2
goto @装备展示面板
[@装备展示面板]
; 装备展示
#IF
#ACT
MOV U9 7
#SAY
<Img|esc=1|show=4|reset=1|img=custom/yxgl/bg.png|bg=1|move=1>
<Layout|x=976.0|y=-48.0|width=80|height=80|link=@exit>
<Button|x=974.0|y=-6.0|pimg=public/1900000511.png|nimg=public/1900000510.png|link=@exit>
<Frames|x=46.0|y=20.0|speed=15|loop=-1|count=62|suffix=.png|prefix=custom\yxgl\tx\tx_>
<Img|x=56.0|y=37.0|esc=0|img=custom/yxgl/tips.png>
<Button|x=90.0|y=109.0|nimg=custom/yxgl/an/an1_0.png|size=18|pimg=custom/yxgl/an/an1_1.png|color=255|link=@本服特色面板>
<Button|x=90.0|y=159.0|nimg=custom/yxgl/an/an2_1.png|size=18|pimg=custom/yxgl/an/an2_0.png|color=255|link=@装备展示面板>
<Button|x=89.0|y=211.0|nimg=custom/yxgl/an/an3_0.png|size=18|pimg=custom/yxgl/an/an3_1.png|color=255|link=@玩法介绍面板>
<Img|x=300.0|y=74.0|esc=0|img=custom/yxgl/15.png>
<Img|x=303.0|y=74.0|esc=0|img=custom/yxgl/16.png>
<ListView|children={2,3,4,5,6,7,8}|x=315.0|y=440.0|width=630|height=42|direction=2|margin=3|loadDelay=0|bounce=0|reload=0>
<ListView|children={9,a0,a1,a2,a3,a4,a5,a6,a7,a8,a9}|x=313.0|y=86.0|width=630|height=338|margin=3|loadDelay=1>
<$STR(S$装备展示列表<$STR(N$大陆标识)>)>
#IF
#ACT
MOV S$选中按钮2 an2-1
MOV S$选中按钮3 an3-1
MOV S$选中按钮4 an4-1
MOV S$选中按钮5 an5-1
MOV S$选中按钮6 an6-1
MOV S$选中按钮7 an7-1
MOV S$选中按钮8 an8-1
MOV S$选中按钮<$STR(N$大陆标识)> an<$STR(N$大陆标识)>-2
;二大陆
#IF
#SAY
<Button|id=2|x=-8.0|y=113.0|size=18|color=255|nimg=custom/yxgl/zbzs/<$STR(S$选中按钮2)>.png|link=@切换大陆#大陆标识=2>
;三大陆
#IF
large U9 2
#SAY
<Button|id=3|x=428.0|y=444.0|size=18|color=255|nimg=custom/yxgl/zbzs/<$STR(S$选中按钮3)>.png|link=@切换大陆#大陆标识=3>
;四大陆
#IF
large U9 3
#SAY
<Button|id=4|x=554.0|y=444.0|size=18|color=255|nimg=custom/yxgl/zbzs/<$STR(S$选中按钮4)>.png|link=@切换大陆#大陆标识=4>
;五大陆
#IF
large U9 4
#SAY
<Button|id=5|x=681.0|y=444.0|size=18|color=255|nimg=custom/yxgl/zbzs/<$STR(S$选中按钮5)>.png|link=@切换大陆#大陆标识=5>
;六大陆
#IF
large U9 5
#SAY
<Button|id=6|x=808.0|y=444.0|size=18|color=255|nimg=custom/yxgl/zbzs/<$STR(S$选中按钮6)>.png|link=@切换大陆#大陆标识=6>
;七大陆
#IF
large U9 6
#SAY
<Button|id=7|x=428.0|y=444.0|size=18|color=255|nimg=custom/yxgl/zbzs/<$STR(S$选中按钮7)>.png|link=@切换大陆#大陆标识=7>
;八大陆
#IF
large U9 7
#SAY
<Button|id=8|x=935.0|y=444.0|size=18|color=255|nimg=custom/yxgl/zbzs/<$STR(S$选中按钮8)>.png|link=@切换大陆#大陆标识=8>
#IF
;等于空不遍历
equal S$装备展示列表<$STR(N$大陆标识)>
#ACT
MOV N$装备展示起始行 <$GetTypeBRow(cfg_装备展示,0,<$STR(N$大陆标识)>)>
MOV N$装备展示结束行 <$formulation[<$GetTypeERow(cfg_装备展示,0,<$STR(N$大陆标识)>)>+1]>
MOV N$装备展示最大列 9
MOV S$装备展示列表<$STR(N$大陆标识)>
MOV N$行开始ID 0
;遍历行
while <$STR(N$装备展示起始行)> < <$STR(N$装备展示结束行)>
MOV S$子元素ID
MOV N$装备展示起始列 1
MOV N$列开始ID 1
goto @添加单排装备展示
INC S$装备展示列表<$STR(N$大陆标识)> <Layout|id=a<$STR(N$行开始ID)>|children={<$STR(S$子元素ID)>}|x=17.0|y=86.0|width=630|height=70|bounce=0|direction=2>
INC N$行开始ID 1
INC N$装备展示起始行 1
endwhile
;遍历列
[@添加单排装备展示]
#act
MOV S$装备名称 <$cfg_装备展示(<$STR(N$装备展示起始行)>_<$STR(N$装备展示起始列)>)>
#IF
;等于空跳出goto循环
not equal S$装备名称
small N$装备展示起始列 N$装备展示最大列
#ACT
;每列元素之间的间距
formulation <$STR(N$装备展示起始列)>*80-80 N$元素横坐标
MOV S$图片ID a<$STR(N$行开始ID)>-<$STR(N$列开始ID)>
INC N$列开始ID 1
MOV S$装备ID a<$STR(N$行开始ID)>-<$STR(N$列开始ID)>
INC S$装备展示列表<$STR(N$大陆标识)> <Img|id=<$STR(S$图片ID)>|x=<$STR(N$元素横坐标)>|y=0|esc=0|img=custom/yxgl/itembg6.png>
INC S$装备展示列表<$STR(N$大陆标识)> <ItemShow|id=<$STR(S$装备ID)>|x=<$STR(N$元素横坐标)>|y=0|width=70|height=70|itemcount=1|itemname=<$STR(S$装备名称)>|bgtype=0|showtips=1>
INC S$子元素ID <$STR(S$图片ID)>,<$STR(S$装备ID)>,
INC N$装备展示起始列 1
;开始执行下一列
INC N$列开始ID 1
goto @添加单排装备展示
#elseact
break
[@切换大陆]
#ACT
MOV N$大陆标识 <$STR(S$大陆标识)>
#OR
equal N$大陆标识 0
small u9 3
#ACT
MOV N$大陆标识 2
goto @装备展示面板
break
#OR
;标识验证，小于等于U9,表示U9为合法
equal N$大陆标识 U9
small N$大陆标识 U9
#act
MOV N$大陆标识 <$STR(S$大陆标识)>
goto @装备展示面板
break
#elseact
MOV N$大陆标识 2
goto @装备展示面板
break
}
页:
[1]